One of the most time consuming task when setting up a computer is the installation and configuration of all the different software programs. Computer companies and others who continually configure systems usually install the software using a pre-configured "Operating System Image". Installation from an Operating System Image can be done unattended and reduces the time required from hours to minutes. This same technique can be used by those involved in refurb projects and allows installation of complete software setups that require a minimum of configuration

Multiple "Operating System Images" can be created to fit the needs of the intended recipients such as:

• Basic Setup
• Children's Educational
• Religious Educational
• Handicapped
• Basic office tools (word processor, spreadsheet, database, etc.)

The Operating System Image process can be divided into three parts:

• Image creation
• Image installation
• Final configuration

Operating System Image Creation

Step 1. Operating System Images that will be installed on a wide variety of hardware are best created on a "generic" computer. Here is a description of a computer used to create images:

• Fast 486 such as a 486DX4-100
• ISA or VLB bus (avoid PCI)
• 16MB ram
• ISA video card (Western Digital or Trident chip sets work fine)
• Should NOT HAVE, sound card, network card or other special cards which will not be present on a target machine where the image will be installed.

Step 2. Install all software on your creation machines hard drive and configure it to suit your purpose

Perform the following operations before making an image or copying the setup to another drive:

• Run a virus check on the drive
• Delete all files from these folders:
  • c:\windows\recent\
  • c:\windows\temp\
  • c:\recycled\
• Run Microsoft REGCLEAN on W95 or SCANREG on W98
• Erase the file c:\windows\win386.swp (this will have to be done from DOS)
• Run Scandisk from DOS

Images can be created in many ways that include commercial or shareware image programs (like Symantec Ghost), data backup programs (Like Microsoft Backup) or simply dedicating the original hard drive as the image and using a program like XXCOPY to copy it to a new drive.

The next step outlines a method for creating a compressed file image at the file level that can be created & restored from DOS. These images have proven to be the most reliable and adaptable to any target drive size or type (IDE, SCSI, etc.). Additionally, with this method, the target drive only needs to be partitioned and formatted with the appropriate FAT system for the image.

This method uses two freeware/shareware programs:

• DOSLFNBK v2.2 - used to backup/restore the long file names
• LHARC v.2.55 - used to compress and create/restore the image file

Since the actual mechanics of this process are a little involved it is best executed using a DOS batch file to automate it.

Here is the code for a batch file that will create an image named C_IMAGE.LZH in C:\ :

@echo off



IF "%1"=="restore" goto RESTOR

echo Image

echo Requires LHARC V2.55 and DOSLFNBK v2.2

echo .

echo Preparing to make an image file of the C:  drive

echo Be certain you have adequate drive space

echo .

echo You may specify a different target directory/folder for the image

echo with the following syntax: Image D:\DATA

echo in this example the file would be created in

echo the D: drive and the DATA directory/folder.

echo .

echo Press ENTER to continue or CTRL C to quit

pause>NUL



rem this section backs up long file names

  doslfnbk c:\ /f c



rem this section  creates the image

if "%1"=="" goto ROOT



cls

echo .

echo Saving file C_IMAGE in %1

echo .

pause

lharc a /r2x1a2 %1\C_IMAGE c:\

goto EXIT



:ROOT

cls

echo .

echo Saving file C_IMAGE in C:\

echo .

pause

lharc a /r2x1a2 c:\C_image c:\

echo .

echo DONE!!!

Echo  The image file C:\C_IMAGE.LZH has been created

 goto EXIT



rem  this section used to restore the image



:RESTOR

  cls

  echo                ****************************

  echo                Install image to a new drive

  echo                ****************************

  echo .

  echo . The TARGET drive should be formatted, but should not contain

  echo   any system boot files.

  echo .

pause



Rem this section restores the image

  lharc x /a2 c:\*.lzh c:\



 rem this section restores the long file names

   doslfnbk C:\ /r /f c



echo .

echo DONE!!

echo .

echo Remove any disk from the A: drive and reboot the system.

echo If the system does not boot, you should boot from a floppy

echo containing the operating system of the image and use the

echo SYS C: command to make the drive bootable.



:EXIT

The above code can be copy & pasted into Notepad and then saved as IMAGE.BAT

To use it to create an image, prepare the drive as outlined above. Copy LHARC.EXE, DOSLFNBK.EXE, and IMAGE.BAT into the root folder C:\ . Restart to a DOS prompt and run IMAGE.BAT from the command line. As an alternate you can create a bootable floppy and copy the three files above to it for use.

When the image creation process is complete you will have the file C:\C_IMAGE.LZH. After creation the image file can be renamed to any name as long as the extension remains .LZH

If you don't put Windows .CAB files in every image (copy them to your new target drive separately) you will be able to store several image files on one CDR and use as needed.

Image installation

1. Partition and format the target drive, be sure to use the appropriate FAT system
2. Make sure the target drive does not contain any operating system boot files
3. Copy the IMAGE file, LHARC.EXE, DOSLFNBK.EXE, and IMAGE.BAT to the target drive root folder, here are some methods to do this:
   • temporarily set the target drive as a slave drive and copy the files. (fastest method)
   • use a Laplink parallel cable and a file transfer program like LAPLINK (DOS), XTLINK, FILEMAVEN (DOS), etc. to copy from computer to computer (slowest method)
   • burn the files to a CDR and use a bootable floppy w/CDROM support to boot the target computer, then copy the files to the target drive
4. Boot the computer from a suitable floppy
5. Change directory to the C:\ drive and type IMAGE.BAT restore

You should see the file names scrolling on the screen as they are restored to the target drive

Final Configuration

7. If your image did not include Windows .CAB file you may want to copy these to the new drive.
8. If you have installed a Windows system, after start up you should:
   • click My Computer
   • click Control Panel
   • click Add New Hardware

This will let Windows find all the devices on the new computer. You may also have to supply device drivers if asked.

After the image has been restored, you can erase the image files that were copied to the target drive.